Pesan error Excel selalu diawali tanda pagar (#) dan menunjukkan jenis masalahnya: #DIV/0! berarti pembagian dengan nol, #N/A berarti nilai tidak ditemukan, #REF! berarti referensi sel hilang, #VALUE! berarti tipe data salah. Cara memperbaikinya tergantung error, bukan sekadar membungkus rumus dengan IFERROR.
Ringkasan: error, arti, dan perbaikan cepat
| Error | Arti singkat | Perbaikan tercepat |
|---|---|---|
#DIV/0! | Membagi dengan nol atau sel kosong | Cek penyebut sebelum membagi |
#N/A | Nilai yang dicari tidak ada | Periksa ejaan dan spasi, pakai IFNA bila memang wajar kosong |
#VALUE! | Tipe data salah, mis. teks dikalikan angka | Ubah teks menjadi angka |
#REF! | Sel atau kolom yang dirujuk sudah dihapus | Perbaiki referensi atau batalkan penghapusan (Ctrl+Z) |
#NAME? | Nama fungsi salah ketik, atau teks tanpa tanda kutip | Periksa ejaan dan tanda kutip |
#NUM! | Angka tidak valid untuk fungsi tersebut | Periksa nilai masukan |
#NULL! | Dua rentang dipisah spasi tetapi tidak berpotongan | Ganti spasi dengan koma atau titik dua |
#SPILL! | Hasil rumus tidak punya cukup ruang kosong | Kosongkan sel penghalang |
#CALC! | Hasil rumus larik kosong atau tidak bisa dihitung | Beri nilai pengganti pada fungsi pembuatnya |
##### | Kolom terlalu sempit | Lebarkan kolom |
Contoh di bawah memakai data penjualan: kolom A produk, B kota, C Qty, D harga, E omzet, dengan data di baris 2 sampai 9.
#DIV/0!
Terjadi saat pembagi bernilai nol atau kosong.
| Input | Rumus | Hasil |
|---|---|---|
| C10 kosong | =E2/C10 | #DIV/0! |
| C10 kosong | =IF(C10=0,"",E2/C10) | (sel kosong) |
Pilih IF ketika Anda ingin sengaja menangani nol. Pembungkus IFERROR juga bisa, tetapi akan ikut menyembunyikan error lain.
#N/A
Fungsi pencarian tidak menemukan nilai yang dicari.
| Input | Rumus | Hasil |
|---|---|---|
| Produk “Webcam” tidak ada di A2:A9 | =VLOOKUP("Webcam",A2:D9,4,FALSE) | #N/A |
| Sama | =IFNA(VLOOKUP("Webcam",A2:D9,4,FALSE),"Belum ada harga") | Belum ada harga |
Jika data terlihat ada tetapi tetap #N/A, penyebabnya biasanya spasi di ujung teks atau angka yang tersimpan sebagai teks. Bersihkan dengan TRIM. Jangan memakai IFERROR untuk semua kasus ini. IFNA hanya menangkap #N/A, sehingga error lain tetap terlihat. Di Google Sheets, FILTER yang tidak menemukan baris juga mengembalikan #N/A.
#VALUE!
Rumus mendapat tipe data yang tidak bisa dihitung.
| Input | Rumus | Hasil |
|---|---|---|
| C2 berisi teks “tiga” | =C2*D2 | #VALUE! |
| D3 berisi teks “Rp 150.000” | =D3*2 | #VALUE! |
| D3 berisi angka 150000 berformat Rupiah | =D3*2 | 300.000 |
Salah satu penyebab klasik: harga diketik lengkap dengan “Rp” sehingga menjadi teks. Ketik angkanya saja, lalu atur tampilan Rp lewat format sel (Ctrl+1). Cek juga dengan ISNUMBER bila ragu.
#REF!
Rumus merujuk sel yang sudah tidak ada, biasanya karena baris atau kolom dihapus. Jika =SUM(E2:E9) merujuk kolom E lalu kolom E dihapus, hasilnya menjadi =SUM(#REF!). Batalkan penghapusan dengan Ctrl+Z, atau tulis ulang referensinya. Mencegahnya: ubah isi kolom menjadi kosong alih-alih menghapus kolom, atau rujuk lewat tabel Excel.
#NAME?
Excel tidak mengenali sesuatu di dalam rumus.
| Input | Rumus | Hasil |
|---|---|---|
| Salah ketik nama fungsi | =SUMM(E2:E9) | #NAME? |
| Teks tanpa tanda kutip | =IF(B2=Jakarta,"Ya","Tidak") | #NAME? |
| Ditulis benar | =IF(B2="Jakarta","Ya","Tidak") | Ya |
#NAME? juga muncul jika Anda memakai fungsi baru seperti XLOOKUP di Excel versi lama yang belum memilikinya. Lihat XLOOKUP vs INDEX dan MATCH untuk pilihan yang jalan di semua versi.
#NUM!
Angka di dalam rumus tidak masuk akal bagi fungsinya.
| Rumus | Hasil |
|---|---|
=SQRT(-4) | #NUM! (akar bilangan negatif) |
=SQRT(4) | 2 |
#NULL!
Excel menganggap spasi di antara dua rentang sebagai operator irisan, yaitu sel yang dimiliki bersama kedua rentang. Jika kedua rentang tidak berpotongan, hasilnya #NULL!.
| Rumus | Hasil |
|---|---|
=SUM(C2:C5 E2:E5) | #NULL! (kolom C dan E tidak berpotongan) |
=SUM(C2:C5,E2:E5) | Jumlah kedua rentang |
Hampir selalu penyebabnya lupa mengetik koma atau titik dua di antara dua rentang.
#SPILL!
Rumus larik dinamis di Excel 365 dan 2021 menumpahkan hasilnya ke banyak sel. Jika ada sel terisi di jalur tumpahan, hasilnya #SPILL! (panduan Microsoft).
| Input | Rumus | Hasil |
|---|---|---|
| G3 berisi catatan, rumus di G2 | =UNIQUE(B2:B9) | #SPILL! |
| G3:G4 dikosongkan | =UNIQUE(B2:B9) | Jakarta, Bandung, Surabaya |
Klik sel yang error. Excel menggambar kotak putus-putus di area tumpahan dan menyebut penyebabnya di ikon peringatan. Penyebab lain: tumpahan masuk ke dalam Tabel Excel, atau area tumpahan terlalu besar. Google Sheets memakai pesan berbeda untuk kasus serupa: “Array result was not expanded because it would overwrite data”.
#CALC!
Mesin hitung Excel tidak bisa menghasilkan larik. Yang paling sering Anda temui adalah FILTER yang tidak menemukan baris.
| Input | Rumus | Hasil |
|---|---|---|
| Tidak ada transaksi di Medan | =FILTER(A2:E9,B2:B9="Medan") | #CALC! |
| Sama, dengan argumen pengganti | =FILTER(A2:E9,B2:B9="Medan","Tidak ada") | Tidak ada |
#CALC! juga dipakai Python di Excel, misalnya saat perhitungan melewati batas data. Pesan Python lain seperti #BLOCKED!, #CONNECT!, dan #BUSY! dijelaskan di halaman pemecahan masalah Microsoft.
#FIELD!
Muncul pada tipe data tertaut (misalnya tipe data Saham atau Geografi di Excel 365) saat rumus meminta kolom yang tidak ada pada tipe data itu, seperti =A2.Populasi bila field tersebut tidak tersedia. Pilih field dari daftar yang muncul setelah mengetik titik. Pesan ini bukan hasil fungsi database seperti DSUM.
Bukan error rumus. Artinya kolom terlalu sempit untuk menampilkan angka atau tanggal. Klik ganda pada garis batas kolom di header untuk melebarkan otomatis. Jika kolom sudah lebar tetapi tetap #####, cek apakah hasil tanggal atau jam bernilai negatif, misalnya =DATE(2025,1,1)-DATE(2025,3,1) pada sel berformat tanggal.
Khusus Google Sheets
| Pesan | Arti | Contoh dan perbaikan |
|---|---|---|
#ERROR! | Rumus gagal dibaca (Formula parse error) | =IF(A1>5 "ya") tanpa koma. Tambahkan koma yang hilang |
#N/A dari FILTER | Tidak ada baris yang cocok | Bungkus dengan IFNA atau tampilkan hasil kosong |
| Circular dependency | Rumus merujuk dirinya sendiri | Ubah rujukan agar tidak melingkar |
Loading... | Data masih diambil (mis. IMPORTRANGE) | Tunggu, atau beri izin akses pada IMPORTRANGE |
Bukan error Excel
Beberapa daftar di internet, termasuk versi lama artikel ini, memuat #MISSING!, #LOCKED!, #FORMULA!, dan #SPILLERROR!. Keempatnya bukan pesan error yang dihasilkan Excel. #ERROR! hanya ada di Google Sheets. Jika Anda melihat pesan seperti itu di Excel, kemungkinan besar berasal dari add-in, tabel pivot, atau teks yang diketik sendiri.
Cara menelusuri error
- Klik sel yang error, lalu lihat ikon peringatan di sebelah kirinya. Pilih Show Calculation Steps untuk menjalankan Evaluate Formula.
- Buka tab Formulas > Evaluate Formula untuk melihat rumus dihitung langkah demi langkah.
- Pakai Trace Precedents untuk melihat sel mana saja yang dipakai rumus.
- Setelah akar masalah ketemu, baru putuskan: dibetulkan, atau sengaja disembunyikan dengan IFERROR atau IFNA. ISERROR dan ISNA berguna untuk menguji tanpa mengganti hasil.
Rumus yang benar sejak awal mengurangi error. Mulailah dari rumus dasar Excel dan pahami operator perbandingan yang menjadi syarat di dalam IF.
Baca juga
- VLOOKUP #N/A padahal data ada: tujuh penyebab dan cara mengujinya satu per satu.
- Angka di Excel tidak bisa dijumlahkan: angka yang sebenarnya teks, dan cara mengubahnya.